Windows 10 Как да забраним автоматичното обновяване в Windows 10.


Създаваме текстов файл с разширение .bat и име без значение,примерно "DisableEnable Windows 10 Automatic Updates",копираме в него следният script code:

@echo off

title Disable/Enable Windows 10 Automatic Updates

color 1f

:Begin UAC check and Auto-Elevate Permissions

:-------------------------------------

REM --> Check for permissions

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.

if '%errorlevel%' NEQ '0' (

echo:

echo Requesting Administrative Privileges...

echo Press YES in UAC Prompt to Continue

echo:

goto UACPrompt

) else ( goto gotAdmin )

:UACPrompt

echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"

echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"

"%temp%\getadmin.vbs"

exit /B

:gotAdmin

if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )

pushd "%CD%"

CD /D "%~dp0"

:--------------------------------------

:Check Windows Version

wmic os get version | find /i "10.">nul 2>nul

if %errorlevel% neq 0 GOTO :Not10

:Check the key:

reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "NoAutoUpdate"|find /i "0x1">NUL 2>NUL

if %errorlevel% neq 0 GOTO :KEYOFF

:KEYON

echo ============================================================

echo Automatic Updates are currently disabled.

echo Would you like to re-enable them? (Y/N)

echo ============================================================

echo.

choice /c yn /n

If %ERRORLEVEL% NEQ 1 GOTO :QUIT

echo Attempting to shut down the Windows Update service if it's running

net stop wuauserv>NUL 2>NUL

echo.

Echo Changing Registry key

REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "NoAutoUpdate" /D 0 /T REG_DWORD /F>NUL 2>NUL

IF %ERRORLEVEL% NEQ 0 GOTO :ERROR

Echo.

Echo Automatic Updates have been enabled

Echo.

goto :QUIT

:KEYOFF

echo ============================================================

echo Automatic Updates are currently enabled.

echo Would you like to disable them? (Y/N)

echo ============================================================

echo.

choice /c yn /n

If %ERRORLEVEL% NEQ 1 GOTO :QUIT

echo Attempting to shut down the Windows Update service if it's running

net stop wuauserv>NUL 2>NUL

echo.

Echo Changing Registry key

REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "NoAutoUpdate" /D 1 /T REG_DWORD /F>NUL 2>NUL

IF %ERRORLEVEL% NEQ 0 GOTO :ERROR

Echo.

Echo Automatic Updates have been disabled

Echo.

goto :QUIT

:QUIT

echo ============================================================

echo Press any key to exit...

echo ============================================================

pause>NUL

goto :EOF

:ERROR

echo ============================================================

echo The script ran into an unexpected error setting reg key.

echo Press any key to exit...

echo ============================================================

pause>NUL

goto :EOF

:Not10

echo ============================================================

echo This script is only designed for Windows 10...

echo Press any key to exit...

echo ============================================================

pause>NUL

goto :EOF

http://i.imgur.com/XSvnIg0.png http://i.imgur.com/McxNHuI.png http://i.imgur.com/qZWOB6t.png

http://forums.mydigi...le-script' target='_blank' class="bbc_url">Източник

Готов .bat файл,стартирайте като администратор!!!

https://mega.nz/#!JA...BBZ03hM1Hd3blhU


2


1 Comment

Отговорено

Това не е скрипт за забраняване на автоматичното обновяване, а за превключване на режима на обновяване.
За истинско конфигуриране на обновяването е най-добре да се използва gpedit.msc

Computer Configuration > Administrative Templates > Windows Components > Windows Update

 

ximg_55ba5501b2422.jpg.pagespeed.gp+jp+j


ximg_55ba551f0e070.png.pagespeed.gp+jp+j

1

Споделете коментара


Адрес на коментара
Сподели в други сайтове

Създайте нов акаунт или се впишете, за да коментирате

За да коментирате, трябва да имате регистрация

Създайте акаунт

Присъединете се към нашата общност. Регистрацията става бързо!


Регистрация на нов акаунт

Вход

Имате акаунт? Впишете се оттук.


Вписване